1 REM CHANGE FILE TYPE
2 REM CHGTYP.BAS
4 REM 990712.0341
10 CLEAR 1024
100 PRINT "FILENAME: ";
110 LINE INPUT F$
120 IF F$="" THEN 100
200 PRINT "1)BINARY 2)ASCII"
210 LINE INPUT A$
220 IF A$="1" OR A$="2" THEN 250
230 GOTO 200
250 PRINT
260 A=0 : IF A$="2" THEN A=255
300 PRINT "0)BASIC PROGRAM"
301 PRINT "1)BASIC DATA FILE"
302 PRINT "2)MACHINE CODE"
303 PRINT "3)TEXT FILE"
310 LINE INPUT T$
320 IF LEN(T$)<>1 THEN 300
330 T=VAL(T$)
340 IF T<0 OR T>3 THEN 300
345 PRINT
350 PRINT "FILENAME:";F$
360 IF A=0 THEN PRINT "BINARY"
361 IF A=255 THEN PRINT "ASCII"
370 ON T+1 GOTO 371,372,373,374
371 PRINT "BASIC PGM":GOTO 380
372 PRINT "BASIC DATA":GOTO 380
373 PRINT "MACH.CODE":GOTO 380
374 PRINT "TEXT":GOTO 380
380 PRINT "CONTINUE? (Y/N) ?";
381 LINE INPUT Q$
382 IF Q$<>"Y" THEN 100
400 D=INSTR(F$,".")
410 IF D<1 THEN 450
420 FL$=LEFT$(F$,D-1)
430 FR$=RIGHT$(F$,LEN(F$)-D)
440 GOTO 500
450 FL$=F$
460 FR$=""
500 FL$=LEFT$(FL$+"        ",8)
510 FR$=LEFT$(FR$+"   ",3)
520 F$=FL$+FR$
550 PRINT "ADJUSTING FILE TYPE"
600 FOR S=3 TO 11
610 M=0
620 DSKI$ 0,17,S,A$,B$
630 T$=A$:GOSUB 1000:A$=T$
640 T$=B$:GOSUB 1000:B$=T$
650 IF M=0 THEN 670
660 DSKO$ 0,17,S,A$,B$
670 NEXT S
680 END
1000 FOR E=0 TO 3
1010 TF$=MID$(T$,E*32+1,11)
1020 IF TF$<>F$ THEN 1070
1025 PRINT "FOUND '"+F$+"' IN 17,";S
1030 TL$=LEFT$(T$,E*32+11)
1040 TR$=RIGHT$(T$,(3-E)*32+19)
1050 T$=TL$+CHR$(T)+CHR$(A)+TR$
1060 M=M+1
1070 NEXT E
1080 RETURN